Windows 10_1511_10586.104可以自製ISO檔嗎？

john823

分享：


適用于 Windows 10 Version 1511 的累積更新 (KB3135173)

更新後版本號為 10586.104

http://download.windowsupdate.com/c/msdownload/update/software/secu/2016/02/windows10.0-kb3135173-x64_8709ec87df2757c6077d2e7178dbf083473f138a.msu

http://download.windowsupdate.com/d/msdownload/update/software/secu/2016/02/windows10.0-kb3135173-x86_31f87a03e38211ca3572506c466c9e2eb0fcdb8e.msu

bruce0702

用DISM指令將KB3135173整合到install.wim
再將整合好的install.wim替換ISO檔內的install.wim即可

bruce0702

測試：
從SW_DVD5_Win_Pro_10_1511_64BIT_ChnTrad_MLF_X20-82404提取install.wim
整合KB3135173..檔案大小從3.23G變成3.68G左右
實體安裝..CMD下winver指令..顯示10586.104

bruce0702

如有需要整合後的install.wim檔再跟我說

nf17b

弄個批次檔跑一下 , 先整合更新再重新打包 ISO 檔
樓上大大的檔案為例
(1) 解壓附加檔案到任一目錄
(2) 把更新檔放到 hotfix_x64 目錄內

(3) 把原始 ISO 的資料提取到 ISOFOLDER 目錄內

(4) 系統管理員身份執行 win10_hotfix_x64 .cmd
整合更新

重新打包 ISO

虛擬機測試


批次檔紅色處自己視情況改一下
@echo off
color 1f
SET TP=%~dp0
SET TP=%TP:~0,-1%
SET MOU=%TP%\mount-temp
SET HOTFIX=%TP%\hotfix_x64
SET DVDLABEL=J_CPRA_X64FREV_ZH-TW_DV5
SET DVDISO=SW_DVD5_Win_Pro_10_1511_64BIT_ChnTrad_MLF_X20-82404.ISO
SET TIME=10/31/2015,03:22:07
cd /d "%TP%

完整的批次檔

1. @echo off
   
2. color 1f
   
3. SET TP=%~dp0
   
4. SET TP=%TP:~0,-1%
   
5. SET MOU=%TP%\mount-temp
   
6. SET HOTFIX=%TP%\hotfix_x64
   
7. SET DVDLABEL=J_CPRA_X64FREV_ZH-TW_DV5
   
8. SET DVDISO=SW_DVD5_Win_Pro_10_1511_64BIT_ChnTrad_MLF_X20-82404.ISO
   
9. SET TIME=10/31/2015,03:22:07
   
10. cd /d "%TP%"
    
11. 
    
12. %windir%\system32\reg.exe query "HKU\S-1-5-19" 1>nul 2>nul || (
    
13. ECHO ----Windows 10 10586 x64 整合更新----
    
14. echo.
    
15. echo.
    
16. echo     -------
    
17. echo  *** 警告 ***
    
18. echo     -------
    
19. echo.
    
20. echo.
    
21. echo 沒有檢測到超級管理員權限
    
22. echo ____________________________________________________________________________
    
23. echo.
    
24. echo 本程序需超級管理員授權
    
25. echo.
    
26. echo 您可以在程序上面右鍵單擊，選擇以管理員身份運行。
    
27. echo.
    
28. echo.
    
29. echo.
    
30. echo 請輸入任意鍵退出程序...
    
31. pause >nul
    
32. goto :eof
    
33. )
    
34. 
    
35. set DISMRoot=%TP%\dism\x86\dism.exe && set OSCDRoot=%TP%\dism\x86\oscdimg.exe
    
36. %windir%\system32\reg.exe query "hklm\software\microsoft\Windows NT\currentversion" /v buildlabex | find /i "amd64" 1>nul && set DISMRoot=%TP%\dism\x64\dism.exe && set OSCDRoot=%TP%\dism\x64\oscdimg.exe
    
37. 
    
38. 
    
39. IF NOT EXIST ISOFOLDER\sources\install.wim ECHO 找不到 ISOFOLDER\sources\install.wim & GOTO :PAU
    
40. IF NOT EXIST ISOFOLDER\boot\etfsboot.com ECHO 找不到 ISOFOLDER\boot\etfsboot.com & GOTO :PAU
    
41. IF NOT EXIST ISOFOLDER\efi\Microsoft\boot\efisys.bin ECHO 找不到 ISOFOLDER\efi\Microsoft\boot\efisys.bin & GOTO :PAU
    
42. 
    
43. ECHO -----Windows 10 10586 x64 整合更新-----
    
44. ECHO 任意鍵開始處理，如需要退出請關閉本窗口。
    
45. ECHO 處理期間請不要打開工作目錄中一些臨時產生的目錄與相應的文件。
    
46. PAUSE >NUL
    
47. 
    
48. IF EXIST %MOU% RD /Q /S %MOU%
    
49. md %MOU%
    
50. 
    
51. CLS
    
52. ECHO ----Windows 10 10586 x64 整合更新----
    
53. ECHO ------------處理第 1 映像------------
    
54. %DISMRoot% /Mount-Wim /WimFile:ISOFOLDER\sources\install.wim /MountDir:%MOU% /Index:1
    
55. %DISMRoot% /Image:%MOU% /Add-Package /PackagePath:%HOTFIX%
    
56. %DISMRoot% /Unmount-Wim /MountDir:%MOU% /Commit
    
57. 
    
58. rd mount-temp
    
59. ECHO 成功添加封包
    
60. 
    
61. ECHO.
    
62. ECHO ----Windows 10 10586 x64 整合更新----
    
63. ECHO ----------- 重新打包 ISO ------------
    
64. ECHO -------------------------------------
    
65. %OSCDRoot% -bootdata:2#p0,e,b"ISOFOLDER\boot\etfsboot.com"#pEF,e,b"ISOFOLDER\efi\Microsoft\boot\efisys.bin" -o -h -m -u2 -udfver102 -t%TIME% -l%DVDLABEL% ISOFOLDER %DVDISO%
    
66. ECHO.
    
67. ECHO 處理結束，任意鍵退出。
    
68. PAUSE >NUL
    
69. EXIT
    
70. 
    
71. :PAU
    
72. ECHO 未能成功處理。
    
73. ECHO 任意鍵退出
    
74. PAUSE >NUL
    
75. EXIT

複製代碼

win10_hotfix_x64.7z

bruce0702

nf17b 發表於 2016-2-11 19:46
弄個批次檔跑一下 , 先整合更新再重新打包 ISO 檔
樓上大大的檔案為例
(1) 解壓附加檔案到任一目錄

請教一下
ECHO ----Windows 10 10586 x64 整合更新----
ECHO ------------處理第 1 映像------------
%DISMRoot% /Mount-Wim /WimFile:ISOFOLDER\sources\install.wim /MountDir:%MOU% /Index:1
%DISMRoot% /Image:%MOU% /Add-Package /PackagePath:%HOTFIX%
%DISMRoot% /Unmount-Wim /MountDir:%MOU% /Commit
這幾行可以單獨執行嗎?還是前面要加上設定路徑
SET TP=%~dp0
SET TP=%TP:~0,-1%
SET MOU=%TP%\mount-temp
SET HOTFIX=%TP%\hotfix_x64

bruce0702

nf17b 發表於 2016-2-11 19:46
弄個批次檔跑一下 , 先整合更新再重新打包 ISO 檔
樓上大大的檔案為例
(1) 解壓附加檔案到任一目錄

我將指令留下我要的部分..可以針對install.wim處理..再配合引導ISO檔放在USB安裝
@echo off
SET TP=%~dp0
SET TP=%TP:~0,-1%
SET wim=%TP%\wim
SET hotfix=%TP%\hotfix64
cd /d "%TP%

set DISMRoot=%TP%\dism\x86\Dism.exe
%windir%\system32\reg.exe query "hklm\software\microsoft\Windows NT\currentversion" /v buildlabex | find /i "amd64" 1>nul && set DISMRoot=%TP%\dism\x64\Dism.exe

%DISMRoot% /Mount-Wim /WimFile:.\install.wim /MountDir:%wim% /Index:1
%DISMRoot% /Image:%wim% /Add-Package /PackagePath:%hotfix%
pause
%DISMRoot% /Unmount-Wim /MountDir:%wim% /Commit

nf17b

實在是很抱歉 , 應該是我沒處理好 , 解壓後右鍵 , 檔案內容解除封鎖


不設變數的批次檔
@echo off
color 1f
cd /d %~dp0

%windir%\system32\reg.exe query "HKU\S-1-5-19" 1>nul 2>nul || (
ECHO ----Windows 10 10586 x64 整合更新----
echo.
echo.
echo     -------
echo  *** 警告 ***
echo     -------
echo.
echo.
echo 沒有檢測到超級管理員權限
echo ____________________________________________________________________________
echo.
echo 本程序需超級管理員授權
echo.
echo 您可以在程序上面右鍵單擊，選擇以管理員身份運行。
echo.
echo.
echo.
echo 請輸入任意鍵退出程序...
pause >nul
goto :eof
)


IF NOT EXIST ISOFOLDER\sources\install.wim ECHO 找不到 ISOFOLDER\sources\install.wim & GOTO :PAU
IF NOT EXIST ISOFOLDER\boot\etfsboot.com ECHO 找不到 ISOFOLDER\boot\etfsboot.com & GOTO :PAU
IF NOT EXIST ISOFOLDER\efi\Microsoft\boot\efisys.bin ECHO 找不到 ISOFOLDER\efi\Microsoft\boot\efisys.bin & GOTO :PAU

ECHO -----Windows 10 10586 x64 整合更新-----
ECHO 任意鍵開始處理，如需要退出請關閉本窗口。
ECHO 處理期間請不要打開工作目錄中一些臨時產生的目錄與相應的文件。
PAUSE >NUL

IF EXIST mount-temp RD /Q /S mount-temp
md mount-temp

CLS
ECHO ----Windows 10 10586 x64 整合更新----
ECHO ------------處理第 1 映像------------
dism\x64\dism.exe /Mount-Wim /WimFile:ISOFOLDER\sources\install.wim /MountDir:mount-temp /Index:1
dism\x64\dism.exe /Image:mount-temp /Add-Package /PackagePath:hotfix_x64
dism\x64\dism.exe /Unmount-Wim /MountDir:mount-temp /Commit

rd mount-temp
ECHO 成功添加封包

ECHO.
ECHO ----Windows 10 10586 x64 整合更新----
ECHO ----------- 重新打包 ISO ------------
ECHO -------------------------------------
dism\x64\oscdimg.exe -bootdata:2#p0,e,b"ISOFOLDER\boot\etfsboot.com"#pEF,e,b"ISOFOLDER\efi\Microsoft\boot\efisys.bin" -o -h -m -u2 -udfver102 -t10/31/2015,03:22:07 -lJ_CPRA_X64FREV_ZH-TW_DV5 ISOFOLDER SW_DVD5_Win_Pro_10_1511_64BIT_ChnTrad_MLF_X20-82404.ISO
ECHO.
ECHO 處理結束，任意鍵退出。
PAUSE >NUL
EXIT

:PAU
ECHO 未能成功處理。
ECHO 任意鍵退出
PAUSE >NUL
EXIT

nf17b

bruce0702 發表於 2016-2-11 23:23
我將指令留下我要的部分..可以針對install.wim處理..再配合引導ISO檔放在USB安裝
@echo off
SET TP=%~dp0

紅色造成的 ?
%DISMRoot% /Mount-Wim /WimFile:.\install.wim /MountDir:%wim% /Index:1
改這樣
%DISMRoot% /Mount-Wim /WimFile:install.wim /MountDir:%wim% /Index:1

bruce0702

nf17b 發表於 2016-2-12 00:03
紅色造成的 ?
%DISMRoot% /Mount-Wim /WimFile:.\install.wim /MountDir:%wim% /Index:1
改這樣

目前是改成這樣
@echo off
cd /d %~dp0
dism\x64\dism.exe /Mount-Wim /WimFile:.\install.wim /MountDir:wim /Index:1
dism\x64\dism.exe /Image:wim /Add-Package /PackagePath:.\hotfix64
pause  清wim\Windows\winsxs\Backup底下的檔案
dism\x64\dism.exe /Unmount-Wim /MountDir:wim /Commit